This is the theme in vincula.. Most everything should be here. eXo labeled it as ; Displays
;--- Displays
raw PROP:*: {
if ($2 == language) echo $color(info2) -ti2 $1 * $msn.ifdecode($nick) sets the room language to $gettok(English.French.German.Japanese.Swedish.Dutch.Korean.Chinese (Simplified).Portuguese.Finnish.Danish.Russian.Italian.Norwegian.Chinese (Traditional).Spanish.Czech.Greek.Hungarian.Polish.Slovene.Turkish.Slovak.Portuguese (Brazilian),$3,46) ( $+ $3 $+ )
else echo $color(info2) -ti2 $1 * $msn.ifdecode($nick) sets the $2 property to: $3-
}
raw 818:*: {
if ($3 == PUID) {
echo $color(info2) -at * Opening $msn.ifdecode($2) $+ 's profile...
var %m, %c, %x, %p http://chat.msn.com/profile.msnw?epuid= $+ $4- , %w @Vincula - $+ $msn.ifdecode($2) $+ 's Profile
window -pk0 %w
%m = $msn.ndll(attach,$window(%w).hwnd)
%m = $msn.ndll(select,$window(%w).hwnd)
%m = $msn.ndll(handler,msn.hnd.prof)
%m = $msn.ndll(navigate,%p)
%msnc.stoppropend = $true
haltdef
}
elseif (($3 == MSNPROFILE) && ($window($msn.get($cid,room)))) {
if ($4 == 1) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) has a regular profile
elseif ($4 == 3) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) $+ 's profile says he is male
elseif ($4 == 5) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) $+ 's profile says she is female
elseif ($4 == 9) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) has a picture in his or her profile
elseif ($4 == 11) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) $+ 's profile has a picture, and says he is male
elseif ($4 == 13) echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) $+ 's profile has a picture, and says she is female
else echo $color(info2) -t $msn.get($cid,room) * $msn.ifdecode($2) does not have a profile
%msnc.stoppropend = $true
haltdef
}
}
alias msn.hnd.prof {
if ($2 == new_window) return S_CANCEL
return S_OK
}
raw 819:*: {
if (%msnc.stoppropend) {
unset %msnc.stoppropend
haltdef
}
}
raw 822:*: {
echo $color(info2) -ti2 $comchan($nick,1) * $msn.ifdecode($nick) is now away: $1-
cline -l $color(gray) $comchan($nick,1) $fline($comchan($nick,1),$nick,1,1)
if ($window($nick) == $nick) echo $color(info2) -t $nick * $msn.ifdecode($nick) is now away: $1-
haltdef
}
raw 821:*: {
echo $color(info2) -ti2 $comchan($nick,1) * $msn.ifdecode($nick) has returned
cline -lr $comchan($nick,1) $fline($comchan($nick,1),$nick,1,1)
if ($window($nick) == $nick) echo $color(info2) -t $nick * $msn.ifdecode($nick) has returned
haltdef
}
raw KNOCK:*: {
if ($2 == 913) echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Access Ban): $nick
elseif ($2 == 471) echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Room is full): $nick
elseif ($2 == 473) echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Room is invite only): $nick
elseif ($2 == 474) echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Banned): $nick
elseif ($2 == 475) echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Need room key): $nick
else echo $colour(info) -t $1 * Knock: $msn.ifdecode($nick) ( $+ $address $+ ) (Numeric: $2 $+ ): $nick
haltdef
}
raw KILL:*: {
halt
}
on *:INPUT:#: {
if (($msn.get($cid,decode)) && ((/* !iswm $1) || (/me == $1))) {
var %p = $left($nick($chan,$me).pnick,1)
if (%p == $left($me,1)) unset %p
if (/me != $1) {
echo $color(own) -ti2 $chan $+(<,$msn.ifdecode(%p $+ $me),>) $1-
if ($msn.get($cid,encode)) .msg $chan $msn.encode($1-)
else .msg $chan $1-
}
else {
echo $color(own) -ti2 * $msn.ifdecode(%p $+ $me) $2-
if ($msn.get($cid,encode)) .describe $chan $msn.encode($2-)
else .describe $chan $2-
}
haltdef
}
}
on *:INPUT:?: {
if (($msn.get($cid,decode)) && ((/* !iswm $1) || (/me == $1))) {
var %p = $left($nick($comchan($me,1),$me).pnick,1)
if (%p == $left($me,1)) unset %p
if (/me != $1) {
echo $color(own) -ti2 $target $+(<,$msn.ifdecode(%p $+ $me),>) $1-
if ($msn.get($cid,encode)) .msg $target $msn.encode($1-)
else .msg $target $1-
}
else {
echo $color(own) -ti2 $target $+(<,$msn.ifdecode(%p $+ $me),>) * $+ $2- $+ *
if ($msn.get($cid,encode)) .msg $target * $+ $2- $+ *
else .msg $target * $+ $2- $+ *
}
haltdef
}
}
on ^*:JOIN:*: {
if (($msn.ini(sounds)) && ($sock(msn.server. $+ $cid)) && ($msn.ini(snd.join) != $null)) splay -w " $+ $msn.ini(snd.join) $+ "
if ((!$msn.ini(jwho)) && ($msn.get($cid,room)) && ($nick === $me)) {
%msnt.jwho = $true
who $chan
}
if ($msn.get($cid,hjoin)) { haltdef | return }
if ($msn.get($cid,decode)) {
if ($nick === $me) {
echo $color(join) -t $chan * Now talking in $chan $iif(%msnc.jointime,$chr(40) $+ Join time: $calc(($ticks - %msnc.jointime) / 1000) seconds $+ $chr(41))
msn.getpass $chan
unset %msnc.*
}
else {
echo $color(join) -t $chan * Joins: $msn.ifdecode($nick) ( $+ $address $+ ): $nick
if ($window($nick) == $nick) echo $color(join) -t $nick * $msn.ifdecode($nick) has joined the room
}
haltdef
}
else {
if (($nick === $me) && ($sock(msn.server. $+ $cid))) {
echo $color(join) -t $chan * Now talking in $chan $iif(%msnc.jointime,$chr(40) $+ Join time: $calc(($ticks - %msnc.jointime) / 1000) seconds $+ $chr(41))
msn.getpass
unset %msnc.*
}
}
}
on ^*:PART:*: {
if ($msn.get($cid,hpart)) { haltdef | return }
if ($msn.get($cid,decode)) {
echo $color(part) -t $chan * Parts: $msn.ifdecode($nick) ( $+ $address $+ ) $+ $iif($1 != $null,( $+ $1- $+ )) $+ : $nick
if ($window($nick) == $nick) echo $color(part) -t $nick * $msn.ifdecode($nick) has left the room
haltdef
}
}
on ^*:TEXT:*:#: {
if ($msn.get($cid,decode)) {
if ($chr(37) $+ $chr(35) $+ * iswm $nick) var %n = $chan
else {
if ($len($nick) >= 50) var %n = $line($chan,$fline($chan,$nick $+ *,1,1),1)
else var %n = $nick
}
var %p = $left($nick($chan,%n).pnick,1)
if (%p == $left(%n,1)) unset %p
echo $color(normal) -tmi2 $chan < $+ %p $+ $msn.ifdecode(%n) $+ > $msn.ifdecode($1-)
haltdef
}
}
on ^*:ACTION:*:#: {
if ($msn.get($cid,decode)) {
if ($chr(37) $+ $chr(35) $+ * iswm $nick) var %n = $chan
else {
if ($len($nick) >= 50) var %n = $line($chan,$fline($chan,$nick $+ *,1,1),1)
else var %n = $nick
}
var %p = $left($nick($chan,%n).pnick,1)
if (%p == $left(%n,1)) unset %p
echo $color(action) -tmi2 $chan $msn.ifdecode(* %p $+ %n $1-)
haltdef
}
}
on ^*:TEXT:*:?: {
if ($msn.get($cid,decode)) {
var %p = $left($nick($comchan($nick,1),$nick).pnick,1)
if (%p == $left($nick,1)) unset %p
if ($window($nick)) echo $color(normal) -tmi2 $nick < $+ %p $+ $msn.ifdecode($nick) $+ > $msn.ifdecode($1-)
else echo $color(normal) -tmi2 $comchan($nick,1) * $+ %p $+ $msn.ifdecode($nick) $+ * $msn.ifdecode($1-)
haltdef
}
}
on ^*:NOTICE:*:#: {
if ($msn.get($cid,decode)) {
echo $color(notice) -tmi2 $chan $msn.ifdecode($+(-,$nick,:,$chan,-) $1-)
haltdef
}
}
on ^*:NOTICE:*:?: {
if (($msn.ini(sounds)) && ($sock(msn.server. $+ $cid)) && ($msn.ini(snd.rwhs) != $null)) splay -w " $+ $msn.ini(snd.rwhs) $+ "
if ($msn.get($cid,decode)) {
echo $color(notice) -tmi2 $comchan($nick,1) $msn.ifdecode($+(-,$nick,-) $1-)
haltdef
}
}
on ^*:RAWMODE:*: {
if ($msn.get($cid,decode)) {
echo $color(mode) -ti2 $chan $msn.ifdecode(* $nick sets mode: $1-)
haltdef
}
}
on ^*:KICK:*: {
if (($msn.ini(sounds)) && ($sock(msn.server. $+ $cid)) && ($msn.ini(snd.kick) != $null)) splay -w " $+ $msn.ini(snd.kick) $+ "
if ($msn.get($cid,hkick)) { haltdef | return }
if ($msn.get($cid,decode)) {
echo $color(kick) -ti2 $chan $msn.ifdecode(* $knick was kicked by $nick $iif($1- != $null,$chr(40) $+ $1- $+ $+ $chr(41))) $+ : $knick
if ($window($knick) == $knick) echo $color(kick) -ti2 $knick $msn.ifdecode(* $knick was kicked by $nick $iif($1- != $null,$chr(40) $+ $1- $+ $chr(41)))
if ($knick == $me) echo $color(kick) -sti2 * You were kicked out of $msn.get($cid,fullroom) by $msn.ifdecode($nick $iif($1- != $null,$chr(40) $+ $1- $+ $chr(41)))
haltdef
}
}
on *:SIGNAL:msn.kill: {
if (($msn.ini(sounds)) && ($sock(msn.server. $+ $cid)) && ($msn.ini(snd.kick) != $null)) splay -w " $+ $msn.ini(snd.kick) $+ "
if ($msn.get($cid,hkick)) { haltdef | return }
scid $1
echo $color(kick) -ti2 $msn.get($1,room) $msn.ifdecode(* $3 was killed by $2 $iif($4- != $null,$chr(40) $+ $4- $+ $+ $chr(41))) $+ : $2
if ($window($2) == $2) echo $color(kick) -ti2 $2 $msn.ifdecode(* $3 was killed by $2 $iif($4- != $null,$chr(40) $+ $4- $+ $chr(41)))
if ($2 == $me) echo $color(kick) -sti2 * You were killed by $msn.ifdecode($2 $iif($4- != $null,$chr(40) $+ $4- $+ $chr(41)))
scid -r
haltdef
}
on ^*:QUIT: {
if ($msn.get($cid,decode)) {
echo $color(quit) -ti2 $msn.get($cid,room) $msn.ifdecode(* Quits: $nick ( $+ $address $+ ) $iif($1 != $null,$chr(40) $+ $1- $+ $+ $chr(41))) $+ : $nick
if ($window($nick) == $nick) echo $color(quit) -ti2 $nick $msn.ifdecode(* $nick has left the room $chr(40) $+ Quit $+ $iif($1- != $null,: $1-) $+ $chr(41))
haltdef
}
}
on ^*:INVITE:#: {
if (($msn.ini(sounds)) && ($sock(msn.server. $+ $cid)) && ($msn.ini(snd.invt) != $null)) splay -w " $+ $msn.ini(snd.invt) $+ "
if ($msn.get($cid,decode)) {
echo $color(invite) -ati2 * $msn.ifdecode($nick) ( $+ $address $+ ) invites you to join $chan
haltdef
}
}
ctcp *:ERR*:*: {
if ($2 == NOUSERWHISPER) {
echo $color(info2) -at * $msn.ifdecode($nick) is not accepting whispers
haltdef
}
else echo $color(info2) -at * Error recieved from $msn.ifdecode($nick) $+ : $2-
}
on ^*:HOTLINK:*:#: {
if ($sock(msn.*. $+ $cid,0) >= 2) {
if ($1 ison $chan) return
if (<*> iswm $1) return
if ($msn.encode($1) ison $chan) return
}
halt
}
etc. etc. etc.
;--- Update checker
Edited Mar 31, 2004 10:46 PM by err0r
