To many sockets for me to even TRY and attempt. Heres a basic socket tutorial, so you can try yourself ..
About: This tutorial was written to give a basic idea to those new to mIRC sockets an idea of how the whole thing works. This tutorial utilizes most of the basic socket commands, as well as some custom aliases. Note: Your aliases do not have to be the same as mine, they're just for examples to make it easier to use and understand.
Step 1: This alias will open a socket to listen on port 1337.
alias opensocket {
socklisten sock1 1337
echo -a [sock] Socket successfully opened on $ip $+ : $+ $sock(sock1).port
}
Usage: /opensocket
Note: In order to be able to accept incoming socket connections, you must first open a listen socket, which is what we are doing with this alias. In order to receive information on a socket, we must first specify a socket name, and the port we would like mIRC to listen on. The port is required when making a socket connection
We now have a socket open on port 1337 by the name of sock1, it will be listening for any incoming connections from another client on that specific port. The following event is required in order to correctly establish the connection between you, and the person or program connecting to mIRC.
Step 2: This event is triggered when a connection is incoming, you must accept the connection using sockaccept to complete it.
on *:socklisten:sock1: {
sockaccept sock2
echo -a [sock] Incoming socket connection accepted!
}
Format: on *:socklisten:sockname: { sockaccept <socket name> }
Note: The new socket name must differ from the current name of the listen socket. In this example, we used "sock2" as the new socket name. The sockname in the event is the name of the listen socket we first opened using the /opensocket alias I wrote.
Step 3: This event will read any incoming data on the newly opened connection.
on *:sockread:sock2: {
sockread %sock.data
echo -a [sock] Incoming Data: %sock.data
}
Format: on *:sockread:sockname: { sockread %variable }
Note: The sockname in the event is the name of the newly opened connection, not the listen socket. Because we assigned the new connection the name of "sock2", we use that name in the sockread event. In order to grab the incoming data, you must use the /sockread command. As shown above, the sockread command is writing all of the incoming data to a variable I created called %sock.data (You can use whatever you want as your variable name). I then echo'd the data to the active window using echo -a.
Step 4: This alias will attempt to connect to your newly opened socket.
alias connsocket { sockopen sock3 $ip 1337 }
Usage: /connsocket
Format: sockopen <name> <ip> <port>
Step 5: This alias will write info to the newly created sock3 connection made with the alias above.
Note: Normally this procedure is done on a separate client, but for the purpose of this tutorial, we'll only use this one client.
Now that we have the connection accepted and established, we can now send information to the socket. In order to do that, you must use the /sockwrite command.
The syntax for that command is as follows:
/sockwrite -n <sockname> <data>
Note: The -n param automatically adds a $crlf to the end of any outgoing data. (not required)
alias writesock { sockwrite -n sock3 $1- }
Usage: /writesock <data>
Example: /writesock How are you doing socket??!?!
Step 6: Close the sockets once you're through with them using the following alias.
alias closesocks {
sockclose sock*
echo -a [sock] All sockets matching sock* have been closed!
}
This alias will close all of the open sockets matching that wildcard criteria, since our socket names were: sock1, sock2, and sock3, using sockclose sock*, would close all of them at once. Make sense?
