Need Access Lister

Anyone good with access list dialogs?

What u need ?

He needs an access list dialog Im thinking ...

There was just a thread for this a few months ago. I bet you could find it pretty easily.

From Error

 

Here is something i put together in a few minutes. It uses an access list that zan made and the export import from vincula.

 

it worked for me in a buzzen test room. It has no frills and really should be worked on to better it's usage. I'm very rusty when it comes to scripting but you should be able to modify this to suit your needs. If anyone wants to improve it be my guest as it's not really my code lol.

Access.txt

 

 

I'm sure someone will have something better soon.

Was needing this one fixed actually rooms list wasnt loading properly, it is blank, not sure what i did wrong am still new to this.

dialog access {
  title "Access List - [/_access]"
  size -1 -1 332 194
  option pixels notheme
  list 1, 6 32 318 134, size
  box "", 2, 2 22 328 170
  button "Remove", 3, 120 168 52 20, ok
  combo 4, 44 4 198 24, drop
  text "Channel", 5, 2 6 40 16
  combo 7, 244 4 84 24, drop
  button "Ok", 6, 270 168 52 20, default ok
  radio "Add", 8, 8 168 52 20, push
  box "Add Access", 9, 334 4 238 188
  text "Type", 10, 342 56 50 16
  combo 11, 400 52 164 26, drop
  text "Mask", 12, 342 86 50 16
  combo 13, 400 82 164 26, edit drop
  text "Duration", 14, 342 114 50 16
  text "Reason", 16, 342 146 50 16
  edit "", 17, 400 142 164 20
  text "Channel", 18, 342 26 50 16
  combo 19, 400 22 164 26, drop
  combo 15, 400 112 164 26, edit drop
  button "Add", 20, 512 166 52 20
  button "Update", 21, 64 168 52 20
  button "Clear", 22, 175 168 52 20
}

on *:dialog:access:init:0: {
  dll $mdx SetMircVersion $version 
  dll $mdx MarkDialog $dname
  dll $mdx SetBorderStyle 3,6,8,20,21,22 staticedge


  dll $mdx SetControlMDX $dname 1 listview report showsel rowselect nosortheader > $mdx.view
  did -i access 1 1 headerdims 40:1 100:2 100:3 100:4
  did -i access 1 1 headertext + 0 Type $+ $chr(9) $+ 0 Mask $+ $chr(9) $+ 0 Set By $+ $chr(9) $+ Reason $+ $chr(9) $+ Duration

  var %x = 1
  while (%x <= $chan(0)) {
    did -a access 4,19 $chan(%x)
    if ($active == $chan(%x)) { did -c access 4,19 %x }
    inc %x
  }
  if ($chan(0) == 0) { did -a access 4,19 No Channels | did -c access 4,19 1 }

  did -a access 7 All
  did -a access 7,11 Owner
  did -a access 7,11 Host
  did -a access 7,11 Voice
  did -a access 7,11 Grant
  did -a access 7,11 Deny
  did -c access 7,11 1

  did -a access 13 *!*@*$*
  did -a access 13 >*!*@*$*
  did -a access 13 $ial($me)
  did -a access 13 $address($me,1)

  did -a access 15 0
  did -a access 15 1
  did -a access 15 15
  did -a access 15 30
  did -a access 15 60
  did -a access 15 120
  did -a access 15 180
  did -a access 15 720
  did -a access 15 1440
  did -c access 15 1

  did -a access 17 Access Dialog

  set -u5 %access. [ $+ [ $$did(access,4) ] ] $true
  access $did(access,4)
}

on *:dialog:access:sclick:8: {
  if ($dialog(access).w <= 400) {
    dialog -s access -1 -1 573 193
    did -c access 8
  }
  elseif ($dialog(access).w > 400) {
    dialog -s access -1 -1 331 193
    did -u access 8
  }
}

on *:dialog:access:sclick:4,7,21: {
  set -u5 %access. [ $+ [ $did(access,4) ] ] $true
  access $did(access,4)
}

on *:dialog:access:sclick:3: {
  access $did(access,4) delete $gettok($gettok($did(access,1).seltext,1,9),6,32) $gettok($gettok($did(access,1).seltext,2,9),5,32)
  set -u5 %access. [ $+ [ $did(access,4) ] ] $true
  access $did(access,4)
}

on *:dialog:access:sclick:22: {
  access $did(access,4) clear
  set -u5 %access. [ $+ [ $did(access,4) ] ] $true
  access $did(access,4)
}

on *:dialog:access:sclick:20: {
  access $did(19) add $did(11) $did(13) $did(15) : $+ $did(17)
  set -u5 %access. [ $+ [ $did(access,4) ] ] $true
  access $did(access,4)
}

raw 803:*: {
  if (%access. [ $+ [ $2 ] ] == $true) {
    did -r access 1
  }
}

raw 804:*: {
  did -a access 1 $gettok($1-,3,32) $gettok($1-,4,32)
  if (%access. [ $+ [ $2 ] ] == $true) {
    if ($3 == $did(access,7)) || ($did(access,7) == all) {
      did -a access 1 $3 $+ $chr(9) $+ $4 $+ $chr(9) $+ $iif($ial($+(*,$6,*),1),$ial($+(*,$6,*),1).nick,$6) $+ $chr(9) $+ $strip($7-)
    }
  }
}

raw 805:*: {
  if (%access. [ $+ [ $2 ] ] == $true) {
    did -i access 1 1 headerdims 50:1 200:2 auto:3 auto:4
  }
}

raw 913:*: {
  if (%access. [ $+ [ $2 ] ] == $true) {
    did -ra access 1 $chr(32) $+ $chr(9) $+ No Access
  }
}

what server are you using it for.. if you are doing it on buzzen you will have to do /access channame list

yes it is for buzzen but not sure what your talking about exactly i am still learning.

look in your init

this line

access $did(access,4)

needs to be

access $did(access,4) list

on buzzen you have to use access channame list to trigger the raws for access

Thanks that helped

yw

Also, for future reference, if you have a question -- include the code your questioning in the first post.